dnl ====================================================================
dnl Copyright (c) 2001, MeepZor Consulting.
dnl All rights reserved.
dnl
dnl The use and distribution of this code or document is
dnl governed by version 1.0.1 of the MeepZor Consulting Public
dnl Licence (MCPL), which may be found on the Internet at
dnl <URL:http://MeepZor.Com/LICENCE>.
dnl
dnl $Id: acinclude.m4,v 1.1 2001/06/15 14:28:58 coar Exp $
dnl

dnl MP_PERL_MODULE(cpan::module [...])
dnl
dnl See if the specified module is available on the system in Perl's
dnl @INC path.  Perl must be installed or this will regard all as being
dnl unavailable.  Each module is checked separately, even if a list is
dnl provided.  The envariable 'mp_missing_pm' is updated if any
dnl modules are not found.
dnl
AC_DEFUN(MP_PERL_MODULE, [
    if test "x${mp_x_perl_was}" = "x" ; then
        AC_PATH_PROG(PERL, perl, "NOT-FOUND")
        mp_x_perl_was=${ac_cv_path_PERL}
    fi
    if test "x${mp_x_perl_was}" = "xNOT-FOUND" ; then
        mp_missing_pm="${mp_missing_pm} $*"
        mp_missing_pm=`eval echo ${mp_missing_pm}`
    else
        for mp_x_module in $* ; do
            AC_MSG_CHECKING(Perl module ${mp_x_module})
            if ${mp_x_perl_was} -e "use ${mp_x_module};" 2> /dev/null ; then
                AC_MSG_RESULT(found)
            else
                AC_MSG_RESULT(not found)
                mp_missing_pm="${mp_missing_pm} ${mp_x_module}"
                mp_missing_pm=`eval echo ${mp_missing_pm}`
            fi
        done
    fi
])